/* make crackpottish rants   acb 29-6-1995 
 * Now requires the C preprocessor
 * modified by motor for rev.Martin 23-10-2000
 *
 * Copyright (C) 1995 Andrew C. Bulhak
 */


// Global variables used:
// v-benefactors                good guys ("the Guardians of theTime", "the Ancient Masters of Brotherhood")
// v-malefactors                metaphysical bad guys ("the Grays"/"Reptoids")
// v-them                       mundane bad guys ("the Illuminati"/"the Black
//                              Lodge')

Start: S;

#include <stdmap.pbi>
#include <format.pbi>

// tentativi di includere il file stdmap per quanto riguarda uppercase


// upcase:  convert an entire string to uppercase

%trans upcase:
	".*": u ;
;


// upcase-first:  convert the first character of a string to its upper-case
// equivalent

%trans upcase-first:
".*": 0 u ;
;

// fine tentativo
// rules

S: sentence-stream 
	paranoid-sentence-stream 
//      secret-hist-sentence-stream
	factoid-paragraph
	exhortation ;

title: solution ": " 
	[ "the solution to all " problem-types " problems"
	| "the end of " evils
	]
	"\n"
;

//
// Sentences
//

// sentences revealing the Secret History of the Universe, or part thereof

secret-hist-sentence-stream:
	"All human history was part of a struggle between "
	benefactors " and " malefactors ". "
	[
		benefactors " came from " 
			["Sirius"|"the Pleiades"|"the stars"|"Arghata"] ", "
		[
			"bringing with them " [
				"the key to " [
					"ultimate "|"omniversal "|"cosmic "|""|
					"universal "|"celestial "
				] 
				[
					"awareness"|"harmony"|"enlightenment"|
					"truth"
				] |
				"the secrets of "["time"|"energy"|"life"]
			]
		] ". "
	]
;

benefactors: v-benefactors<<new-benefactors ;
malefactors: v-malefactors<<new-malefactors ;

new-benefactors: "the Church of the New Flash" | "the Temple of the New Flash"
	| "the New Flesh Brotherhood"
;

new-malefactors: "the FBI" | "the Unknowns" | "the counterspionage"
	| "the Old Ones" | "the Secret BioChemical laboratory" | "the Dream Police" | "the Secret Masters"  | "the New World Order" | "the New Word Order"
	| "the Army" | "the Secret Underground World Society"
;

// paranoid sentences, i.e., those about conspiracies, suppression, etc.

paranoid-sentence-stream:
	they " destroyed " one-who-knew-too-much " because he knew too much. "
	| one-who-knew-too-much " knew " ["too much"|"all"] " about "
	solution ["; "|["; that"|". That"] " is why "] they " destroyed him. "
	| "All " ["books"|"news"|"journalistic reports"|"historical accounts" | "police reports" | "scientific reports"] " were " 
	["altered"|"rewritten"|"controlled"|"censored"|"purged"] " to " ulterior-purpose
	| "They altered the Bible to " ulterior-purpose
	| they " don't want anyone to know the " something-of-issue solution
	 [""|" and are willing to "["destroy"|"exterminate"|"eliminate"|"silentiate"] 
	" anyone who gets in their way as they did " one-who-knew-too-much 
	] ". "
	| "They " 
	["altered the DNA code"|"ruined the holy ground of the mother Earth"|"polluted the seas and the earth" | "altered the unspeakable Truths about the meaning of Life" | "changed the environmental status"] 
	" to destroy its " 
	["environmental"|"hidden"|"geometric"|"inner"|"harmonic"] " equilibrium. "

	;


ulterior-purpose: ["hide"|"conceal"] " the " something-of-issue solution ". ";

// "the cosmic secret of *", "the truth about *"

something-of-issue: cond-upcase([[""|"cosmic "]"truth"]) " about "
	| cond-upcase([[""|"cosmic "]"secret"]) " of "
;

they:   v-them<<new-they | new-they ;

new-they: "THEY" | "they" | "the bio-tech companies" | "the mundane devil sons" | "the Solar Temple adepts" | "the Branch Davidians" | "the multinational corporations" | "these charismatic megalomaniac" | "the military lobby
	| "the Knights Templar" | "the Nine Unknown Men" | "the Black Lodge"
	| "the Secret Masters" | "the Secret Overlords" | "they" 
	| "the Secret Underground " [""|"World "] "Society" 
	| "the Freemasons";

one-who-knew-too-much: "Wilhelm Reich" | "Von Neumann" | "Giordano Bruno" | "Henry Lee Lucas" | "Charles Manson" | "John Lennon" | "Trent Reznor" | "Theodore Kaczinsky" 
	 ;

sentence-stream: simple-statement justification 
	law " is encoded in " 
	["the Bible"|"the works of Shakespeare"|"the decimal expansion of pi" | "the Revelation Book"]
	". "
	| 
	[""
	  |["Great "["minds"|"men"|"personalities" | "scientists"]|"Eminent researchers"]
	    " throughout history " "(" [eminent ", "]+ " etc.) "
	    " agree that "
	  |"The " ["Aztecs" | "Egyptians" | "Sumerians" | "Christian Mistics"]
	   " knew that "
	]
	  law " is the " 
		[ "guiding principle of" | "governing law of"
		| trans-adj " principle behind" ] " "
	["all creation" | "the stars" | "all nature" | "the Universe"]
	[""|
	  " and yet it is virtually " ["unknown"|"unheard of"] ". "
	  [""|"Why is that? "] 
	"This is because it has been " 
	cond-upcase([[""|"ruthlessly "] "suppressed"]) 
	cond-upcase(" throughout history")
	]
	". "
	| "ALL modern " ["evils"|"common man's evils" | "natural disasters"|"problems"|"social ills" | "ecological disasters" | "social desorders"] 
	" stem from the failure to recognise " 
	[""|"and " ["live"|"be governed"] " by "]
	law ". "
;

eminent: "Einstein" | "Newton" | "Tesla" | "Velikovsky" | "Larson" | "Reverend Jim Jones" | "Charles Manson" | "John Kennedy" | "Aum Shinri Kyo" | "Jeffrey Lundgreen" | "James Warren Jones"
	| "Dr Jack Kevorkian" ;

simple-statement: numeric-analogy(["three"|"four"|"five"|"twelve"|"forty"]);

numeric-analogy(number): "Just as there are " number " " 
	@number>append-things ", there are " number " " 
	@number>append-things ". "
;

justification: "This is because of " cond-upcase(law) ". "
;

append-things:
	".*" -> "$"/"-things"
;

three-things: "entities in the Holy Trinity" | "dimensions"
	| "colours on the flag" // note that this applies to _many_ flags
	| "component colours in white light" //| "Stooges"
;

four-things: "seasons" | "cardinal directions" | "letters in the name of God"
	| "gospels in the Bible" | "suits in a deck of cards"
	| "corners of the Earth" | "races of " ["Man"|"humanity"] 
	| "fundamental elements";

five-things: "axioms of Euclid's Geometry" | "fingers on a human hand"
	| "sides to the pyramid on the US dollar bill"
	| "days in a working week" | "vowels in the Alphabet"
;

seven-things: "days in the week" | "cavities in the human body"
	| "electrons in a nitrogen atom" | "deadly sins"
;

twelve-things: "Apostles" | "hours on a clock" | "inches in a foot" 
	| "months" | "signs of the Zodiac" | "eggs in a dozen" ;

forty-things: "days of the Universal Deluge" | "years of age when Esau get married with Judith" | "days required for embalming" | "days, when Jesus was in the desert, being tempted by the Serpent" | "years, when the LORD make the land of Egypt desolate among devstate lands, and her cities will be desolate forty years among ruined cities" | "years of Solomon reign in Jerusalem over all Israel" | " years the LORD delivered the Israelites into the hands of Philistines" | "years the LORD's anger burned against Israel and he made them wander in the desert" | "nights and forty days of deluge" 
;

// concrete factoids

factoid-paragraph:
	concrete-factoid factoid-consequence
;

factoid-consequence:
	cond-upcase("only") " from this value can one derive the "
	cond-upcase(["true structure of matter"|"missing mass of the universe"| "secret meaning of life"
	|"true orbits of the planets"|"universe's missing day"]) ". ";

concrete-factoid: number-name " is " bogus-number ". "
	| "the true " [""|"hidden "|"suppressed "] "value of pi is 3."
	["0"|"1"|"2"|"3"|"4"|"5"|"6"|"7"|"8"|"9"]+ 
	[""|"; all mathematics textbooks have been "
	["altered"|"rewritten"|"changed"]" to "["hide"|"conceal"] " this"]
	". "
;

number-name: "the " 
	cond-upcase([["cosmic"|"universal"|"psychic"|"mystical"|"trascendent"] " " law-adj " constant"]);

bogus-number: ["1"|"2"|"3"|"4"|"5"|"6"|"7"|"8"|"9"] 
	["0"|"1"|"2"|"3"|"4"|"5"|"6"|"7"|"8"|"9"]* 
	[""|"." [["0"|"1"|"2"|"3"|"4"|"5"|"6"|"7"|"8"|"9"]+]+ ]
;

//
// Exhortations and the like
//

exhortation: cond-upcase([[
	"End " evils
	] " -- " imperative])
	| "Achieve " achievements " " [ "now" | "today" ] "! "
	"Just follow these " {num_steps=3..5; step=1} $num_steps 
	" easy steps.\n"
	%repeat(step,num_steps)
	["" | "IT'S THAT EASY!" ! "JOIN THE FAMILY OF THE NEW FLESH" |"FREE YOUR SOUL! CLEAN YOUR MIND!" | "NOTHING COULD BE SIMPLER!"]
;

step: $step ". "
	[
	["Adopt"|"Learn"|"Memorise"] " " solution "." |
	[["Adopt"|"Accept"] " " solution " as"|
	"Make " solution | "Let " solution " be"
	]" your guide." |
	"Reject the " cond-upcase(evil-adj) [""|" and " cond-upcase(evil-adj)] 
		" doctrine of "
		["evolution"|"the spherical Earth"|"Minimum Message Length"
				    |"self-proclamed divinities and false prophets" | "mistical chupacabras"
		|"Freudian psychology"|"relativity"|"capitalism"] "." |
	"Turn away from " ["the "|"Satan's "] "international "
	["money power"|"media brainwashing " ["empire"|"cartel"]]"."
	] "\n"
	{ step=step+1 }
;

evil-adj: "evil" | "immoral" | "Satanic" | "sinful"| "amoral" | " mundane" ;

imperative: "adopt " [ solution | long-solution ] " now! " ;

long-solution: "government based on " solution
;

problem-types: problem-type ", " problem-type " and " problem-type
;

problem-type: "economic" | "political" | "financial" | "health"
	| "energy" | "sexual" | "spiritual" | "psicotic"
;

achievements: achievement
	| [ achievement ", " ] + achievement " and " achievement
	| [ achievement ", " ] "etc. "
;

achievement: ["immeasurable wealth" | "untold riches" ]
	| [ "ultimate " | "" ] achievement-2;

achievement-2:
	"enlightenment" 
	| "omniversal awareness" | "sexual attractiveness"
	| "cosmic power" ;

evils: evil ", " [ evil ", " ] + "etc.";

evil: "wars" | "unemployment" | "racism" | "poverty" | "famine"
	| "violence" | "disease" | "drug addiction" | "overpopulation"
	| "pollution" | "genital delirium" | "illusion of safety" 
;

solution:
	theory-name " " [ "physics" | "theory" |"doctrine" ] | law | law ;

law:    v-law-1<<new-law | v-law-2<<new-law
	| v-law-1<<new-law | v-law-2<<new-law
	| new-law ;

new-law:         ["the law of " law-name|"the LAW of " law-name>upcase]
	| "the " ["" | trans-adj " "] "principle of " law-name
	| "the " ["" | trans-adj>upcase " "] "principle of " law-name>upcase
	| ["God's"|"Nature's"] " law of " law-name
	| law-adj " law"
// not strictly laws per se, but similar enough grammatically
	| "the cycle of " law-name
;

// transcendental adjectives: "the * principle of Universal Normalisation"

trans-adj: "cosmic" | "divine" | "eternal" | "fundamental" ;

// laws: "the law of *"

law-name: law-adj " " law-subject
	| law-adj " " law-subject
	| law-adj "-" law-adj " " law-subject
;

law-adj: [""|""|"electro-"]["volumetric" | "atomic" | "harmonic" | "universal" | "cosmic" | "psychic" | "consciousness" | "natural" | "time" | "temporal" ]
;

law-subject: "normalisation" | "equivalence" | "justice" | "totality"
	| "duality" | "truth" | "compensation" | "equality"
;

// theory names: "* physics"

theory-name: ["resonation" | "vibrational"]
	| theory-adj " " theory-subject " " theory-modality
	| theory-adj " " theory-modality
;

theory-adj: "unified" | "resonating" | "harmonic" | "cosmic" | "total"
	| "universal" | "quantum"
;

theory-subject: "reality" | "energy" | "gravity"
;

theory-modality: "field" | "wave" | "vector" | "matrix" | "totality" ;

// utility rules

cond-upcase(foo): foo | foo>upcase | foo | foo>upcase ;